Capture the flag with Moose

In today's post, I'll show some ways to get program options via flags (--flags) I discovered recently.

CPAN is crowded with Getopt::* modules, but I'm going to explore the Moose universe.

Moose

At $work, we often have write commandline apps that end with lots of parameters and flags, and 'shift @ARGV' is not an elegant nor flexible solution. I've been using GetOpt::Long for years, but now, using Moose, I discovered an extension Called MooseX::Getopt.


MooseX::Getopt

This Moose eXtension allows you to fill attributes of an object directly from commandline.

	package Person;
	use Moose;
	has 'id' => (is => 'rw', isa => 'Int');
	has 'name' => (is => 'rw', isa => 'Str'); #We'll get it from the id in a database
	1;
	my $p = Person->new(id=>1);
	print $p->dump;
	__DATA__
	run with: perl ./Person.pm
	output:
	$VAR1 = bless( {
	'id' => 1
	}, 'Person' );

view raw Person.pm hosted with ❤ by GitHub

We just have to use MooseX::Getopt in our Class, and change the creation of the object from Foo->new to Foo->new_with_options.

Tada!

	package Person;
	use Moose;
	with 'MooseX::Getopt';
	has 'id' => (is => 'rw', isa => 'Int');
	has 'name' => (is => 'rw', isa => 'Str'); #We'll get it from the id in a database
	1;
	my $p = Person->new_with_options(id=>1);
	print $p->dump;
	__DATA__
	run with: perl ./Person.pm
	output:
	$VAR1 = bless( {
	'ARGV' => [],
	'id' => 1,
	'extra_argv' => []
	}, 'Person' );
	run with: perl ./Person.pm --id=3
	output:
	$VAR1 = bless( {
	'ARGV' => [
	'--id=3'
	],
	'id' => 3,
	'extra_argv' => []
	}, 'Person' );
	run with: perl ./Person.pm --idd=3
	output:
	STDERR:
	Unknown option: idda
	usage: Person.pm [long options...]
	--id
	--name

view raw Person.pm hosted with ❤ by GitHub

Now, our program can get all Foo's attributes through the commandline. Note that if you try an invalid flag, it will output the accepted ones.

- But wait, I do not want to allow users initialize all attrs.

Ok, then we should hide the attr under a name beginning with underscore, and set the accessor to our desired name. MooseX::Getopt will understand you don't want it to be accessible through command line options.

	package Person;
	use Moose;
	with 'MooseX::Getopt';
	has 'id' => (is => 'rw', isa => 'Int');
	has '_name' => (is => 'rw', isa => 'Str', accessor=>'name'); #We'll get it from the id in a database, prefix _ and make accessor same as before
	1;
	my $p = Person->new_with_options(id=>1);
	print $p->dump;
	__DATA__
	run with: perl ./Person.pm --id=3 --name="hola"
	output:
	Unknown option: name
	usage: Person.pm [long options...]
	--id

view raw Person.pm hosted with ❤ by GitHub

MooseX::SimpleConfig

The summum of DWIM is you can also exploit the same introspection capabilities to enable configuration files to setup the execution of the files. And it costs you just one line.

with 'MooseX::SimpleConfig';

	package Person;
	use Moose;
	with 'MooseX::SimpleConfig'; # We enable configfiles. YAML,XML,JSON,INI ...
	with 'MooseX::Getopt';
	has 'id' => (is => 'rw', isa => 'Int');
	has '_name' => (is => 'rw', isa => 'Str', accessor=>'name');
	1;
	my $p = Person->new_with_options();
	print $p->dump;
	__DATA__
	run with: perl ./Person.pm --configfile=a.ini
	a.ini contents:
	id=3
	output:
	$VAR1 = bless( {
	'ARGV' => [
	'--id=3'
	],
	'id' => 3,
	'extra_argv' => []
	}, 'Person' );

view raw Person.pm hosted with ❤ by GitHub

The code above will activate an extra flag (--configfile) where you can indicate where to reach the configuration file.

There are more goodies you can add on top of these modules, but for now, I think it's enough for me. :)

From these findings, you can see, Moose is not only a great OOP platform for perl but a higher level base for perl hackers to put stuff on.

Thanks Perl community.